コンストラクタ; 新しい int オブジェクトを作成します。int.toString() と int.valueOf() を使用するには、int コンストラクタを使用する必要があります。int オブジェクトのプロパティを使用する場合は、コンストラクタを使用しません。new int コンストラクタは、主にプレースホルダーとして使用します。int オブジェクトは、パラメータをプリミティブ値に変換する int() 関数とは異なります。

関連項目

var n1:int = new int(3.4);
var n2:int = new int(-10);
  

数値のストリング表現を指数表現で返します。ストリングには、fractionDigits パラメータでの指定に従って小数点の前に 1 桁、小数点以下に最大 20 桁が含まれます。

var num:Number = 315003;
trace(num.toExponential(2)); // Output: 3.15e+5

数値のストリング表現を固定小数点表現で返します。固定小数点表現とは、fractionDigits パラメータでの指定に従って、小数点以下の特定数の桁をストリングに含めたものです。fractionDigits パラメータの有効範囲は 0 ～ 20 です。この範囲外の値を指定すると例外がスローされます。

var num:Number = 7.31343;
trace(num.toFixed(3)); // Output: 7.313

var num:Number = 4;
trace(num.toFixed(2)); // Output: 4.00

数値のストリング表現を指数表現または固定小数点表現で返します。ストリングには、precision パラメータで指定された桁数が含まれます。

var num:Number = 31.570;
trace(num.toPrecision(3)); // Output: 31.6

var num:Number = 4000;
trace(num.toPrecision(3)); // Output: 4.00e+3

int オブジェクトのストリング表現を返します。

var myint:int = new int(9);
trace(myint.toString(2)); // output: 1001
trace(myint.toString(8)); // output: 11
  

次の例では、結果が 16 進数値になります。

var r:int = new int(250);
var g:int = new int(128);
var b:int = new int(114);
var rgb:String = "0x"+ r.toString(16)+g.toString(16)+b.toString(16);
trace(rgb); // 0xfa8072
  

指定された int オブジェクトのプリミティブな値を返します。

var numSocks = new int(2);
trace(numSocks.valueOf()); // 2
  

表現可能な 32 ビット符号付き整数の最大値、2,147,483,647 です。

trace("int.MIN_VALUE = "+int.MIN_VALUE);
trace("int.MAX_VALUE = "+int.MAX_VALUE);
 

このコードは、次の値を記録表示します。

int.MIN_VALUE = -2147483648
int.MAX_VALUE = 2147483647
 

表現可能な 32 ビット符号付き整数の最小値、-2,147,483,648 です。

trace("int.MIN_VALUE = "+int.MIN_VALUE);
trace("int.MAX_VALUE = "+int.MAX_VALUE);
     

このコードは、次の値を記録表示します。

int.MIN_VALUE = -2147483648
int.MAX_VALUE = 2147483647
     

1. 2 つの int 変数、a と b をコンストラクタで宣言します。
2. addIntegers() メソッドで 2 つの int を追加します。
3. 3 つ目の int 変数 c に parseInteger() の結果を割り当て、 渡されたストリングの有効性をチェックして int データ型が受け取り可能な範囲の整数値であることを確認します。 有効な場合はストリングの整数値に相当する int を返します。
4. addIntegers() を使用して、int 変数a と c を同時に追加します。

package {
    import flash.display.Sprite;

    public class IntExample extends Sprite {    
        public function IntExample() {
            var a:int = 512;
            var b:int = -128;
            
            trace(addIntegers(a, b)); // 384

            var c:int = parseInteger("32");
            
            trace(addIntegers(a, c)); // 544
        }
            
        public function addIntegers(a:int, b:int):int {
            return a + b;
        }
        
        public function parseInteger(str:String):int {
            var num:Number = parseInt(str);
            if(!isNaN(num) && num <= int.MAX_VALUE && num >= int.MIN_VALUE) {
                return int(num);
            }
            
            return 0;
        }
        
    }
}